// This file is under GNU General Public License 3.0

 // see LICENSE.txt

 // generated files of this template are under BSD License 2.0

 // generate message functions

 // Copyleft (c) 2017, p≡p foundation

 // Written by Volker Birk

 include yslt.yml2

 tstylesheet {

     include standardlib.ysl2

     include ./functions.ysl2

     function "pEp_imports"

         | IMPORTS Identity, IdentityList, TID, Hash FROM PEP;

     function "header"

     ||

     -- This file is under BSD License 2.0

     -- «@name» protocol for p≡p

     -- Copyright (c) 2016-2018 p≡p foundation

     -- Written by Volker Birk

     ||

     template "/" {

         apply "protocol", 0, mode=overview;

         apply "protocol/fsm", 0, mode=individual;

     }

     template "protocol", mode=overview

         document "generated/{yml:lcase(@name)}.asn1", "text" {

         call "header";

         ||

         «yml:ucase(@name)»

             { iso(1) org(3) dod(6) internet(1) private(4) enterprise(1) pEp(47878) «yml:lcase(@name)»(«@id») }

         DEFINITIONS AUTOMATIC TAGS EXTENSIBILITY IMPLIED ::=

         BEGIN

         `` for "fsm" | IMPORTS «@name» FROM «yml:ucase(@name)»;

         «@name» ::= CHOICE {

             `` for "fsm" |> «yml:lcase(@name)» [APPLICATION «@id»] «@name»`if "position()!=last()" > , `

         }

         END

         ||

     }

     template "fsm", mode=individual

         document "generated/{yml:lcase(@name)}.asn1", "text" {

         call "header";

         ||

         «yml:ucase(@name)»

             { iso(1) org(3) dod(6) internet(1) private(4) enterprise(1) pEp(47878) «yml:lcase(../@name)»(«../@id») «yml:lcase(@name)»(«@id») }

         DEFINITIONS AUTOMATIC TAGS EXTENSIBILITY IMPLIED ::=

         BEGIN

         EXPORTS «@name»;

         `` call "pEp_imports"

         Version ::= SEQUENCE {

             major INTEGER (0..255) DEFAULT «version/@major»,

             minor INTEGER (0..255) DEFAULT «version/@minor»

         }

         `` apply "message", 0, mode=impl;

         «@name» ::= SEQUENCE {

             header SEQUENCE {

                 sequence INTEGER  -- always increases

             },

             payload CHOICE {

             `` for "message" |>> «yml:mixedCase(@name)» [APPLICATION «@id»] «@name»`if "position()!=last()" > ,`

             }

         }

         END

         ||

     }

     template "message", mode=impl

     ||

     «@name» ::= SEQUENCE {

     `` for "field|auto" |> «func:asn1name()» «func:asn1type()»`if "position()!=last()" > ,`

     }

     ||

 }